Vlookup函數(shù)示例大全

　　Vlookup函數(shù)的教程網(wǎng)上已非常多了，而貼近工作用的Vlookup函數(shù)應(yīng)用示例卻很少。今天分享一期Vlookup函數(shù)示例大全，希望能給大家的工作帶來(lái)幫助。

　　【例1】查找個(gè)人信息

　　=VLOOKUP($B18,$C$7:$H$15,COLUMN(B1),0)

　　注：Colum(b1)的結(jié)果是2，當(dāng)公式向右復(fù)制時(shí)可以生成3，4，5，..

　　【例2】合并兩個(gè)表格

　　F2單元格公式

　　=VLOOKUP(B2,$B$14:$F$22,MATCH(F$1,$B$13:$F$13,0))

　　公式說(shuō)明：用Match函數(shù)查找表1的標(biāo)題在表2中的位置

　　【例3】讓兩個(gè)表格同類商品排序完全一樣

　　F2單元格公式

　　=IFERROR(VLOOKUP($B2,$B$12:$D$16,COLUMN(A1),),"")

　　公式說(shuō)明：IFERROR函數(shù)用來(lái)屏蔽錯(cuò)誤值

　　【例4】制作工資條

　　=VLOOKUP($G96,$A$96:$E$104,COLUMN(B1),)

　　公式說(shuō)明：根據(jù)序號(hào)從工資表中查找對(duì)應(yīng)的信息

　　【例5】計(jì)算個(gè)人所得稅

　　=(G28-3500)*VLOOKUP(G28-3500,C28:E34,2)-VLOOKUP(G28-3500,C28:E34,3)

　　公式說(shuō)明：當(dāng)Vlookup最后一個(gè)參數(shù)為1或省略時(shí)，查找為近似匹配。即查找比指定值小且最接近的值。

　　【例6】模糊查找產(chǎn)品名稱（包含查找）

　　=VLOOKUP("*"&F41&"*",$B$41:$D$47,3,0)

　　注：*是通配符，代表任意多個(gè)字符

　　【例7】帶特殊符合的字符查找

　　=VLOOKUP(SUBSTITUTE(F52,"~","~~"),B$52:C$56,2,0)

　　注：由于~* ？在公式中有通配符用法，遇到被查找的字符串中含有這3個(gè)字符就用Substitute替換為~~、~*和~？

　　【例8】逆向查找

　　=VLOOKUP(G61,IF({1,0},C61:C69,B61:B69),2,)

　　公式說(shuō)明: 本公式只做了解，遇到逆向查找，建議使用Index+Match函數(shù)。

　　=INDEX(B60:B69,MATCH(G61,C60:C69,0))

　　【例9】16年與17年單價(jià)核對(duì)，表格核對(duì)（帶通配符），結(jié)果顯示多N 或 少N

　　=TEXT(VLOOKUP(SUBSTITUTE(B73,"*","~*"),$F$73:$G$92,2,)-C73,"少0.00;多0.00;")

　　公式說(shuō)明:Text可以設(shè)置數(shù)字顯示的格式

　　【例10】Vlookup多條件查找

　　A112 =B112&C112

　　H112 =VLOOKUP(F112&G112,A112:D120,4,0)

　　公式說(shuō)明：Vlookup也可以使用IF({1,0}的數(shù)組形式實(shí)現(xiàn)多條件查找，但運(yùn)行效率太慢，所以建議使用輔助列連接再查找的方法。

　　【例11】庫(kù)存單價(jià)的監(jiān)控。銷售單價(jià)>庫(kù)存單價(jià)時(shí)填充紅色背景

　　設(shè)置方法：選取區(qū)域 - 條件格式 - 新建規(guī)則 - 使用公式確定... - 在下面框中輸入公式：

　　=H2>VLOOKUP(F2,A:C,3,0)

　　最后點(diǎn)“格式”按鈕設(shè)置填充色為紅色

　　【例12】銀行存款最近30天到期提醒。表中要有某天匯總金額，也要有明細(xì)金額。

　　設(shè)置方法：

　　步驟1 添加輔助列，根據(jù)到期日生成 到期日+序列（目的是對(duì)同一個(gè)日期編序號(hào)，方便Vlookup一對(duì)多查找）

　　=D2&"-"&COUNTIF(D$2:D2,D2)

　　步驟2 設(shè)置到期日公式，H2單元格輸入=Today() ,H3=H2+1,然后H3公式向下復(fù)制

　　步驟3 設(shè)置求和公式，用來(lái)統(tǒng)計(jì)每個(gè)到期時(shí)需要還款的總金額

　　=SUMIF(D:D,H2,C:C)

　　步驟4 用Vlookup查找各行明細(xì)數(shù)據(jù)

　　J2單元格公式

　　=IFERROR(VLOOKUP($H2&"-"&J$1,$A:$D,2,0)&":"&VLOOKUP($H2&"-"&J$1,$A:$D,3,0),"")

　　公式說(shuō)明： 這里把H列日期&第1行的數(shù)字作為查找內(nèi)容，在A列中進(jìn)行查找，然后返回 B列 & C列的數(shù)據(jù)，

【Vlookup函數(shù)示例】相關(guān)文章：

常用函數(shù)圖像03-11

(精選)常用函數(shù)圖像03-11

（優(yōu)秀）常用函數(shù)圖像03-12

函數(shù)知識(shí)點(diǎn)03-01

[精選]函數(shù)知識(shí)點(diǎn)03-01

(經(jīng)典)常用函數(shù)圖像15篇03-12

函數(shù)知識(shí)點(diǎn)(合集)03-02

常用函數(shù)圖像15篇[薦]03-11

常用函數(shù)圖像優(yōu)選[15篇]03-12

示例方法在消除客戶異議中的應(yīng)用09-17